furnace (packaged by artemis)

media-sound/furnace/Manifest

@@ -0,0 +1,2 @@
+DIST furnace-0.6-adpcm-ef7a217.zip 11910 BLAKE2B d498b9f2ccabc11a2796351fc09b0722e0d949eff1d26b5b853dcf748c57e44534d8e61ade965c5c70101e64299371bec7891788aedefd8aef09c9ba79ef39e8 SHA512 f5b2e073b8576d58b8c724d1351796583a74822f12d60cbc36bb83a26a8918dc7a1bc97ad71c2463940f5072d82f2d291815ed3b895610d1a88e4d6868533342
+DIST furnace-0.6.tar.gz 44552370 BLAKE2B fd91ab161e309d6c3637fa0c70ea3100f70da98e0044ced1743b0f5416cf6fd9f4f4d307c87776c0a4cfd202ff118d814409bd69f23445443c22265c0630b1fc SHA512 e24aca8e26961c53121869aafa041bf507748e4d4886761ca4a755ad31ba98ce228114009ffb34333d6737fe4759bfa47cd733457863c2f767c01686728c3798

media-sound/furnace/furnace-0.6.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="a multi-system chiptune tracker compatible with DefleMask modules"
+HOMEPAGE="https://github.com/tildearrow/furnace"
+SRC_URI="
+	https://github.com/tildearrow/furnace/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/superctr/adpcm/archive/ef7a217154badc3b99978ac481b268c8aab67bd8.zip -> ${P}-adpcm-ef7a217.zip
+"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="jack"
+
+RDEPEND="
+	dev-libs/libfmt
+	media-libs/alsa-lib
+	media-libs/libglvnd
+	media-libs/libsdl2
+	media-libs/libsndfile
+	media-libs/portaudio
+	media-libs/rtmidi
+	sci-libs/fftw
+	sys-libs/zlib
+	x11-themes/hicolor-icon-theme
+	jack? ( virtual/jack )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	# adpcm is a git submodule in-tree, and thus not included in the
+	# github-generated source bundle. We move it in here.
+	rmdir -v "${S}/extern/adpcm" || die "couldn't remove existing adpcm stub directory"
+	mv -v "${WORKDIR}/adpcm-"* "${S}/extern/adpcm" || die "failed to move adpcm directory into place"
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_GUI=ON
+		-DSYSTEM_FFTW=ON
+		-DSYSTEM_FMT=ON
+		-DSYSTEM_LIBSNDFILE=ON
+		-DSYSTEM_PORTAUDIO=ON
+		-DSYSTEM_RTMIDI=ON
+		-DSYSTEM_ZLIB=ON
+		-DSYSTEM_SDL2=ON
+		-DWITH_JACK="$(usex jack ON OFF)"
+	)
+	cmake_src_configure
+}