diff --git a/gnome-extra/zenity/Manifest b/gnome-extra/zenity/Manifest
new file mode 100644
index 0000000..4587c7e
--- /dev/null
+++ b/gnome-extra/zenity/Manifest
@@ -0,0 +1 @@
+DIST zenity-3.44.2.tar.xz 3095752 BLAKE2B 07d5b9aa673ae1e719bbd8d2ff85394ce19b9e77c36c3b6cf73d6b806dbcb0ab6322d13e66a715ebf5aefc14fa289a31367d0f0abd6ceaa9df7e3d7d12049492 SHA512 60f139b18db9ddf95a9c3481b08a3b99dd56ce457a49d99dc33f59570837e8498e8819bdd130c915a08e40042b2f3af583bd0fe4498adb8152632bd044137f2f
diff --git a/gnome-extra/zenity/zenity-3.44.2.ebuild b/gnome-extra/zenity/zenity-3.44.2.ebuild
new file mode 100644
index 0000000..c91c267
--- /dev/null
+++ b/gnome-extra/zenity/zenity-3.44.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Tool to display dialogs from the commandline and shell scripts"
+HOMEPAGE="https://wiki.gnome.org/Projects/Zenity"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~loong ~ppc ~ppc64 ~riscv x86 ~amd64-linux ~x86-linux"
+IUSE="libnotify webkit"
+
+# TODO: X11 dependency is automagically enabled
+RDEPEND="
+	>=x11-libs/gtk+-3.16.0:3[X]
+	>=dev-libs/glib-2.43.4:2
+	libnotify? ( >=x11-libs/libnotify-0.6.1:= )
+	webkit? ( >=net-libs/webkit-gtk-2.8.1:4.1 )
+	x11-libs/libX11
+
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.4
+	virtual/pkgconfig
+"
+src_configure() {
+	local emesonargs=(
+		$(meson_use libnotify)
+		$(meson_use webkit webkitgtk)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	# Not really needed and prevent us from needing perl
+	rm "${ED}/usr/bin/gdialog" || die "rm gdialog failed!"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}